ඉලක්කමක් සටහන් කළ විට අකුරින් රුපියල් කීයදැයි දක්වමු- අපේම Function එකක් Excel වලට එකතු කරමු 2 ෴

 ඔබ එක්සෙල් කොපමණ හොදින් දැනගත්තද ඇතැම් ගැටළු විසදීමට ඔබට එස්සෙල් හී ඇති Function වනු ඇත. නමුත් අප දැනුමෙන් පොහොසත් නම් අලුතින් Function එක්සෙල් වෙත එකතු කිරීමේ හැකියාව එක්සෙල්  ලබාදී ඇත. මේ ගැන වැඩි විස්තර දැනගැනීමට අවශ්‍ය නම් හා අලුතින් Function එකක් ඇතුළත් කිරීම සඳහා   අපේම Function එකක් Excel වලට එකතු කරමු  යනුවෙන් මාතෘකාව යෙදූ Function එක්සෙල් වෙත ඇතුළත් කරගන්නා ආකාරය විස්තර වන ලිපිය පළමුවෙන් කියවන්න.


බොහෝවිට අප විසින් එක්සෙල් හී මුදලින් අගයක් සටහන් කළ පසුව එය අකුරින් රුපියල් කීයක්දැයි දැක්විය හැකි Function එකක් එක්සෙල්වෙත මේ වන තෙක් හඳුන්වා දී නැත. නමුත් ඔබ මේ වන තෙක් ලබා ඇති දැනුමින් එවැනි Function එකක් ඇතුළත් කරනු ලබන ආකාරය පිළිබඳව හොඳ අවබෝධයක් ලබාදීමට මා උත්සාහ ගනිමි. පහත දැක්වෙන උදාහරණය විමසිලිමත්ව බලන්න.

 

මෙම =NumberToText() යන Function එක වෙත ආදේශ කරනු ලබන සෙල් එකෙහි ඇති අගය රුපියල් වලින් අක්ෂර වලින් දක්වන බව ඔබට වැටහෙනු ඇත. එය සිදු කරනුයේ කෙලෙසින්ද ඔබ කිසිවක් නොකරන්න පහත දැක්වෙන VB code එක කොපි කොට ඉහත ලිපියේ දක්වා ඇති පරිදි Modules එකක් ලබාගෙන එයට Paste කරන්න. දැන් ඔබගේ Function එක ක්‍රියාත්මක වනු ඇත. 


Function NumberToText(ByVal MyNumber)
    Dim Rupees, Cents, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Thousand "
    Place(3) = " Million "
    Place(4) = " Billion "
    Place(5) = " Trillion "

    MyNumber = Trim(Str(MyNumber))
    DecimalPlace = InStr(MyNumber, ".")
    If DecimalPlace > 0 Then
        Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Rupees
        Case ""
            Rupees = "No Rupees"
        Case "One"
            Rupees = "One Rupees"
         Case Else
            Rupees = Rupees & " Rupees"
    End Select
    Select Case Cents
        Case ""
            Cents = " and No Cents"
        Case "One"
            Cents = " and One Cent"
              Case Else
            Cents = " and " & Cents & " Cents"
    End Select
    NumberToText = Rupees & Cents
End Function

Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
    End If
    ' Convert the tens and ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function

Function GetTens(TensText)
    Dim Result As String
    Result = "" ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "Ten"
            Case 11: Result = "Eleven"
            Case 12: Result = "Twelve"
            Case 13: Result = "Thirteen"
            Case 14: Result = "Fourteen"
            Case 15: Result = "Fifteen"
            Case 16: Result = "Sixteen"
            Case 17: Result = "Seventeen"
            Case 18: Result = "Eighteen"
            Case 19: Result = "Nineteen"
            Case Else
        End Select
    Else ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Twenty "
            Case 3: Result = "Thirty "
            Case 4: Result = "Forty "
            Case 5: Result = "Fifty "
            Case 6: Result = "Sixty "
            Case 7: Result = "Seventy "
            Case 8: Result = "Eighty "
            Case 9: Result = "Ninety "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function

Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "One"
        Case 2: GetDigit = "Two"
        Case 3: GetDigit = "Three"
        Case 4: GetDigit = "Four"
        Case 5: GetDigit = "Five"
        Case 6: GetDigit = "Six"
        Case 7: GetDigit = "Seven"
        Case 8: GetDigit = "Eight"
        Case 9: GetDigit = "Nine"
        Case Else: GetDigit = ""
    End Select
End Function

ආයේ කවදාවත් Function මදි කියලා දුක්වෙන්න ඔනේ නෑ. ඔබට ඒක කරන්න පුළුවන්.

0 අදහස් හා මතවාද:

Copyright © 2013 kotuwegedara.com